<%
Const FilePath = "2.xml"
Dim Action:Action = Trim(Request("Action"))
Dim ID
Dim PlugName:PlugName = Trim(Request("PlugName"))
Dim PlugUrl:PlugUrl = Trim(Request("PlugUrl"))
Dim PlugAdminUrl:PlugAdminUrl = Trim(Request("PlugAdminUrl"))
Select Case Action
 Case "Add"
  Call Add
 Case "SaveAdd"
  Call SaveAdd
 Case Else
  Call Main
End Select
Sub Main()
 set tt=new ASPXML
 tt.Path=server.MapPath(FilePath)'第一步先选择文件路径
 tt.Data="Data" '第二步选择数据库
 tt.open '打开
 tt.SelectTable("Plug") '选择表
 'tt.SelectItem "PlugName","雨哲" '查询条件 如果读出所有 这里不要
 'tt.delectTable() '删除这个表
 'tt.SelectItem "ID","1" '这里是查询ID为1的记录
 'tt.Xml_Item=tt.Xml_Count 'tt.Xml_Item 是第几条记录 tt.Xml_Count是记录总数
 If tt.Xml_Bof or tt.Xml_Eof Then
  Response.Write "尚无数据"
  Response.End
 End If
 Response.Write "<table>"
 Response.Write "  <tr>"
 Response.Write "  </tr>"
 do while not(tt.Xml_Bof or tt.Xml_Eof)
  Response.Write "  <tr>"
  Response.Write "    <td>" & tt.read("ID") & "</td>"
  Response.Write "    <td>" & tt.read("PlugName") & "</td>"
  Response.Write "    <td>" & tt.read("PlugUrl") & "</td>"
  Response.Write "    <td>" & tt.read("PlugAdminUrl") & "</td>"
  Response.Write "  </tr>"
  tt.MoveNext()
 loop
 Response.Write "</table>"
 tt.close '关闭
End Sub
Sub Add()
 response.write "<form name='form1' method='post' action='?Action=SaveAdd'>"
 response.write "  插件名称：<input type='text' name='PlugName' size='30' ><br>"
 response.write "  插件地址：<input type='text' name='PlugUrl' size='40'><br>"
 response.write "  管理地址：<input type='text' name='PlugAdminUrl' size='40'><br>"
 response.write "  <input type='submit' value='提交'> <input type='reset' value='重置'>"
 response.write "  </form>"
End Sub
Sub SaveAdd()
 set tt=new ASPXML
 tt.Path=server.MapPath(FilePath)'第一步先选择文件路径
 tt.Data="Data" '第二步选择数据库
 tt.open '打开
 tt.SelectTable("Plug") '选择表
 tt.addnew ' 添加记录
 tt.add "PlugName",PlugName '写入值
 tt.add "PlugUrl",PlugUrl '写入值
 tt.add "PlugAdminUrl",PlugAdminUrl '写入值
 tt.update '保存记录
 tt.close '关闭
End Sub
Class ASPXML
Private objDom,objnodes,objTable,Xml_Array,XMLnodes,ID,brstr,NewXMLnode,NewXMLcooky
Public Path,Data,Xml_Eof,Xml_Bof,Xml_Item,Xml_Count
'打开文档
Public Sub Open()
 set objDom=server.CreateObject("Microsoft.XMLDOM")
 objDom.load Path
 set objnodes=objdom.documentElement.SelectSingleNode("//"+Data+"").ChildNodes
 set XMLnodes=objdom.documentElement.SelectSingleNode("//"+Data+"")
End Sub
'选择表
Public Function SelectTable(Table)
 objTable=Table
 Xml_Count=-1
 Xml_Eof=false
 Xml_Bof=false
 'Xml_Item=2
 If Xml_Item="" then
  Xml_Item=0
 End If
 GETCount()
 ChkCount()
End Function
Public Sub MoveNext() '下移一行
 Xml_Item=Xml_Item+1
 ChkCount()
End Sub
Public Sub MoveLast() '上移一行
 Xml_Item=Xml_Item-1
 ChkCount()
End Sub
Public Function Read(key) '读出值
 Read=objnodes(int(Xml_Array(Xml_Item))).selectSingleNode(key).text
End Function
Public Function Write(key,viold) '写入
 objnodes(int(Xml_Array(Xml_Item))).selectSingleNode(key).text=viold
End Function
Public Function SelectItem(key,viold) '查询字段
 Xml_AllTableWords=""
 For i=0 To Xml_Count
  xml_viold=objnodes(int(Xml_Array(i))).selectSingleNode(key).text
  If xml_viold=viold Then
   Xml_AllTableWords=Xml_AllTableWords+"|"+Xml_Array(i)
  End If
 Next
 StrPtr = instr(Xml_AllTableWords, "|")
 Xml_AllTableWords = mid(Xml_AllTableWords, StrPtr+1)
 Xml_Array=split(Xml_AllTableWords , "|")
 Xml_Count=UBound(Xml_Array)
 ChkCount()
End Function
Public Sub AddNew() '新加记录
 NewXMLnode=""
 If XMLnodes.hasChildNodes Then
  ID = XMLnodes.lastchild.firstchild.text+1
 Else
  ID=1 '如是没有字子节点则是第一次ID号设为1
 End If
 Brstr=chr(13)&chr(10)&chr(9)
 NewXMLcooky=Brstr&"<"&objTable&">"&Brstr &"<ID>"&ID&"</ID>"&Brstr
End Sub
Public Function Add(key,viold) '添加数值
 NewXMLcooky=NewXMLcooky&"<"&key&">"&viold&"</"&key&">"&Brstr
 NewXMLnode=NewXMLcooky&"</"&objTable&">"&chr(13)
End Function
Public Function delect(key,viold) '删除记录
 for i=0 to Xml_Count
  if ISkeyOk(key,viold) then
   XMLnodes.removechild(objDom.selectsinglenode("//"&objTable&"["&key&"='"&viold&"']"))
  end if
 next
 objDom.save(Path)
End Function
Public Function DelectTable() '删除表
 for i=0 to Xml_Count
  XMLnodes.removechild(objDom.selectsinglenode("//"&objTable))
 next
 objDom.save(Path)
End Function
Public Sub update() '更新修改表
 if NewXMLnode<>"" then
  set objXML2=Server.CreateObject("Microsoft.XMLDOM")
  objXML2.loadXML(NewXMLnode) '建立一个新XML对像
  set rootNewNode=objXML2.documentElement '把XML版片段读入内存中
  XMLnodes.appendChild(rootNewNode) '获得objXML2的根节点
 end if
 objDom.Save(Path)
End Sub
Public Sub CLOSE() '关闭
 set objnodes=nothing
 set objDom=nothing
 'Response.Write(objTable)
End Sub
Private Function GETCount()
 Xml_AllTableWords=""
 Xml_AllCount=-1
 for each element in objnodes
  Xml_AllCount=Xml_AllCount+1
  If element.nodename =objTable then
   Xml_AllTableWords=Xml_AllTableWords+"|"+cstr(Xml_AllCount)
  end if
 next
 StrPtr = instr(Xml_AllTableWords, "|")
 Xml_AllTableWords = mid(Xml_AllTableWords, StrPtr+1)
 Xml_Array=split(Xml_AllTableWords , "|")
 Xml_Count=UBound(Xml_Array)
End Function
Private Function ChkCount()
 if Xml_Count<0 then
  Xml_Bof=true
 end if
 if Xml_Item>Xml_Count then
  Xml_Eof=true
 end if
End Function
Private Function ISkeyOk(key,viold)
 ISkeyOk=false
 if not(XMLnodes.hasChildNodes) then
  exit Function
 end if
 for each timent in objnodes
 If timent.nodename =objTable then
  set pobjnodes=timent.ChildNodes
  for each yyment in pobjnodes
   if yyment.nodename=key and yyment.text=viold then
    ISkeyOk=true
    exit Function
   end if
  next
 end if
 next
End Function
End Class
%>